%randomterrain%,0
%terraintype%,0
%randomenvironment%,0
%animalenvironment%,0
%animalniche%,1
%randomherd%,0
%worldsize%,2
%atmosphere%,3
%randomevents%,2
%includebiome%,1
%extradata%,1
%exactweight%,2
%integrity%,2
%randomsize%,1
%weight%,1
%weapondata%,2
%swimmerweapons%,2
%standardweapon%,2

@randomterrain,1,Generate a random terrain type?,Yes,No
@terraintype,3,If "no" choose the terrain type:,Clear (Road/Open),Prairie (Plain/Steppe),Rough (Hills/Foothills),Broken (Badlands),Mountain (Alpine),Forest (Woods),Jungle (Rainforest),River (Stream/Creek),Swamp (Bog),Marsh (Wetland),Desert (Dunes),Beach (Shore/Sea Edge),Surface (Ocean/Sea),Shallows (Ocean/Sea),Depths (Ocean/Sea),Bottom (Ocean/Sea),Sea Cave/Cavern,Sargasso (Seaweed),Ruins/(Old City),Cave/Cavern,Chasm (Crevasse/Abyss),Crater (Hollow)
@randomenvironment,1,Generate a random environment (using standard rules and taking terrain type into account)?,Yes,No
@animalenvironment,1,If "no" choose the environment type:,Land (Normal),Swimmer,Amphibian,Triphibian,Flyer
@swimmerweapons,2,(House Rule) Use alternative natural weapons table for swimmers?,Yes,No
@animalniche,1,Choose an animal niche to fulfill:,Any,Herbivore,Omnivore,Carnivore,Scavenger
@randomherd,2,Choose generation method for number of animals in herd:,Do not generate a number,Dice code only,Exact number of specimens
@worldsize,2,Choose the world size:,Asteroid or Small,Normal,Large
@atmosphere,3,Choose the atmosphere:,Vacuum,Thin,Standard,Dense/Exotic
@randomevents,2,Allow event entries to be produced (for encounter tables)?,Yes,No
@extradata,1,Generate extra data (biome + weight + hits + attack modifier + natural weapons + armour + behaviour)?,Yes,No
@randomsize,1,Randomise the creature's size/weight?,Yes,No
@weight,1,If "no" specify the weight class code from 1 to 20 (note that size class 13 is invalid):
@includebiome,1,Include the biome data in the results?,Yes (Good for direct generation),No (Better for encounter tables)
@exactweight,2,(House Rule) Calculate a more exact weight?,Yes,No
@integrity,2,(House Rule) Calculate MTWiki RCS Integrity instead of Hits?,Yes,No
@weapondata,2,Provide extended natural weapon/armour data?,Yes,No
@standardweapon,2,(House Rule) Apply the weight modifier to weapon damage during generation instead of during attacks?,Yes (Single DV),No (DV plus Throw)

%typedm%,0
%weightdm%,0

%herdsize%,0

%environmenttype%,1
%swimmer%,0
%amphibian%,0
%triphibian%,0
%flyer%,0

%roll%,0
%doonce%,0
%temp%,0
%eventflag%,0

%weightroll%,0

%niche%,0
%method%,0

%weaponhits%,0
%weaponbonus%,0
%pen%,0
%blk%,0

%armourdm%,0

:Start
1,[FxnClearVariables]
_{If~%randomterrain%=1 ?|terraintype={Dice~1d22}|}[Terrain Modifier]
_[FxnTypeRoll]{If~%animalniche%=1?[Animal Table 2d6]/
_{Select~%animalniche%,2,[Herbivore=%roll%],3,[Omnivore=%roll%],4,[Carnivore=%roll%],[Scavenger=%roll%]}}
_{If~%eventflag%=0?
_[Special Attribute]
_{If~%randomsize%=1?[FxnWeightRoll]/|weightroll=%weight%|}
_{If~%herdsize%>0 ?{If~%randomherd%>1 ?{If~%randomherd%=3 ? ×{Dice~%herdsize%d6}/, %herdsize%D Herd}}}
_[Animal Data]
_/|eventflag=0|}

#Terrain Types, from Referee's Manual p.34:
# Clear (Road/Open),Prairie (Plain/Steppe),Rough (Hills/Foothills),Broken (Badlands),Mountain (Alpine),
# Forest (Woods),Jungle (Rainforest),River (Stream/Creek),Swamp (Bog),Marsh (Wetland),Desert (Dunes),
# Beach (Shore/Sea Edge),Surface (Ocean/Sea),Shallows (Ocean/Sea),Depths (Ocean/Sea),
# Bottom (Ocean/Sea),Sea Cave/Cavern,Sargasso (Seaweed),Ruins (Old City),Cave/Cavern,
# Chasm (Crevasse/Abyss),Crater (Hollow)
:Terrain Type
1,Clear
2,Prairie
3,Rough
4,Broken
5,Mountain
6,Forest
7,Jungle
8,River
9,Swamp
10,Marsh
11,Desert
12,Beach
13,Sea Surface
14,Sea Shallows
15,Sea Depths
16,Sea Bottom
17,Sea Cave
18,Sargasso
19,Ruins
20,Cave
21,Chasm
22,Crater

:Animal Table 1d6
1,[Scavenger=%roll%]
2-4,[Herbivore=%roll%]
5,[Omnivore=%roll%]
6,[Carnivore=%roll%]

:Animal Table 2d6
2,[Scavenger=%roll%]
3,[Omnivore=%roll%]
4,[Scavenger=%roll%]
5,[Omnivore=%roll%]
6-8,[Herbivore=%roll%]
9,[Carnivore=%roll%]
10,{If~%randomevents%=2?[Animal Table 2d6]/Event|eventflag=1|}
11,[Carnivore=%roll%]
12,[Carnivore=%roll%]

:Terrain Modifier
1,|typedm+{Select~%terraintype%,
# Clear +3
_1,+3,
# Prairie +4
_2,+4,
# Broken -3
_4,-3,
# Forest -4
_6,-4,
# Jungle -3
_7,-3,
# River +1
_8,+1,
# Swamp -2
_9,-2,
# Desert +3
_11,+3,
# Beach +3
_12,+3,
# Surface +2
_13,+2,
# Shallows +2
_14,+2,
# Depths -4
_15,-4,
# Bottom -2
_16,-2,
# Sea Cave -2
_17,-2,
# Sargasso -4
_18,-4,
# Ruins -3
_19,-3,
# Cave -4
_20,-4,
# Chasm -1
_21,-1,
_0}|
_|weightdm+{Select~%terraintype%,
# Broken -3
_4,-3,
# Forest -4
_6,-4,
# Jungle -2
_7,-2,
# River +1
_8,+1,
# Swamp +4
_9,+4,
# Marsh -1
_10,-1,
# Desert -3
_11,-3,
# Beach +2
_12,+2,
# Surface +3
_13,+3,
# Shallows +2
_14,+2,
# Sargasso -2 
_18,-2,
# Cave +1
_20,+1,
# Chasm -3
_21,-3,
# Crater -1
_22,-1,
_0}|

:Herbivore
<|method=Grazer|
0,Filter|herdsize=1||method=Filter|
1-2,Filter|method=Filter|
3-6,Intermittent|method=Intermittent|
7,Grazer
8,Grazer|herdsize=1|
9,Grazer|herdsize=2|
10,Grazer|herdsize=3|
11,Grazer|herdsize=2|
12,Grazer|herdsize=4|
13,Grazer|herdsize=5|
> Herbivore|niche=Herbivore|

:Omnivore
<|method=Gatherer|
0-1,Gatherer
2,Eater|method=Eater|
3,Gatherer
4,Eater|herdsize=2||method=Eater|
5,Gatherer
6,Hunter|method=Hunter|
7,Hunter|herdsize=1||method=Hunter|
8,Hunter|method=Hunter|
9,Gatherer
10,Eater|herdsize=1||method=Eater|
11,Hunter|herdsize=1||method=Hunter|
12,Gatherer
13,Gatherer
> Omnivore|niche=Omnivore|

:Carnivore
<|method=Pouncer|
0,Siren|method=Siren|
1,Pouncer
2,Siren|method=Siren|
3,Pouncer
4,Killer|herdsize=1||method=Killer|
5,Trapper|method=Trapper|
6,Pouncer
7,Chaser|method=Chaser|
8,Chaser|herdsize=3||method=Chaser|
9,Chaser|method=Chaser|
10,Killer|method=Killer|
11,Chaser|herdsize=2||method=Chaser|
12,Siren|method=Siren|
13,Chaser|herdsize=1||method=Chaser|
> Carnivore|niche=Carnivore|

:Scavenger
<|method=Carrion-Eater|
0,Carrion-Eater|herdsize=1|
1,Carrion-Eater|herdsize=2|
2,Reducer|herdsize=1||method=Reducer|
3,Hijacker|herdsize=1||method=Hijacker|
4,Carrion-Eater|herdsize=2|
5,Intimidator|herdsize=1||method=Intimidator|
6,Reducer|method=Reducer|
7,Carrion-Eater|herdsize=1|
8,Reducer|method=Reducer|
9,Hijacker|method=Hijacker|
10,Intimidator|method=Intimidator|
11,Reducer|herdsize=1||method=Reducer|
12,Hijacker|method=Hijacker|
13,Intimidator|herdsize=1||method=Intimidator|
> Scavenger|niche=Scavenger|

:FxnWeightRoll
1,|roll={Dice~2d6}|
# Weight DM
_|roll+%weightdm%|
# World Size DM
_{If~%worldsize%=1?|roll+1|/{If~%worldsize%=3?|roll-1|}}
_|roll>1||roll<20||weightroll=%roll%|
# Reroll any 13s, applying a one-time only +6 DM on the first 13 rolled
_{If~%roll%=13?{If~%doonce%=0?|doonce=1||weightdm+6|}[FxnWeightRoll]}

:FxnArmourRoll
1,|roll={Dice~2d6}|
# Bonus from animal niche
_|roll+%armourdm%|
_{If~%roll% = 1 ?{If~%doonce% = 0 ?|doonce=1||armourdm+6|}[FxnArmourRoll]}
_{If~%roll% = 12 ?{If~%doonce% = 0 ?|doonce=1||armourdm+6|}[FxnArmourRoll]}

:FxnTypeRoll
1,|roll={Dice~2d6}||roll+%typedm%||roll>0||roll<13|

:FxnNicheNaturalWeaponsRoll
1,|roll={Dice~2d6}|{Select~%niche%,1,|roll-3||roll>1|,2,|roll+4||roll<20|,3,|roll+8||roll<20|,|roll+0|}

:FxnNicheNaturalArmourBonus
1,{Select~%niche%,
# Scavengers get +1 to armour
_0,|armourdm+1|,
# Herbivores get +2 to armour
_1,|armourdm+2|,
# Carnivores get -1 to armour
_3,|armourdm-1|,
# No modification for omnivores
_}

:FxnSetEnvironmentType
1,{If~%swimmer%=1?, Swimmer|environmenttype=2|/
_{If~%amphibian%=1?, Amphibian|environmenttype=3|/
_{If~%triphibian%=1?, Triphibian|environmenttype=4|/
_{If~%flyer%=1?, Flyer|environmenttype=5|}}}}

# Special Attributes (environment ability)

:Special Attribute
1,{If~%randomenvironment%!=1?[Special Attribute User]/
_|roll={Dice~2d6}|
_{Select~%atmosphere%,
_1,|roll-2||roll>2|,
_2,|roll-1||roll>2|,
_3,|roll+1||roll<12|,}
_{Select~%terraintype%,
_8,[Special Attribute River=%roll%],
_9,[Special Attribute Swamp=%roll%],
_10,[Special Attribute Marsh=%roll%],
_12,[Special Attribute Beach=%roll%],
_13,[Special Attribute Sea=%roll%],
_14,[Special Attribute Sea=%roll%],
# Changed: In sea depths and the sea bottom, there are only swimmers.
_15,|swimmer=1|,
_16,|swimmer=1|,
_17,[Special Attribute Sea=%roll%],
_18,[Special Attribute Sea=%roll%],
_[Special Attribute General=%roll%]}}

:Special Attribute User
1,{Select~%animalenvironment%,
_2,|swimmer=1|,
_3,|amphibian=1|,
_4,|triphibian=1|,
_5,|flyer=1|,
_|swimmer=0|}

:Special Attribute River
2,|swimmer=1||weightdm+1|
3,|amphibian=1||weightdm+1|
5-10,
11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-5|

:Special Attribute Swamp
2,|swimmer=1||weightdm-3|
3,|amphibian=1||weightdm+1|
4,|amphibian=1||weightdm+1|
5-10,
11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-5|

:Special Attribute Marsh
2,|swimmer=1||weightdm-6|
3,|amphibian=1||weightdm+2|
4,|amphibian=1||weightdm+1|
5-10,
11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-5|

:Special Attribute Beach
2,|swimmer=1||weightdm+1|
3,|amphibian=1||weightdm+2|
4,|amphibian=1||weightdm+2|
5-10,
11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-5|

:Special Attribute Sea
# Changed: Amphibians have been bumped from the 5-6 range to the 3-4 range.
#    There were far too many amphibians generated for sea environments.
2,|swimmer=1||weightdm+2|
3,|amphibian=1||weightdm+2|
4,|amphibian=1|
5,|swimmer=1||weightdm+2|
6,|swimmer=1||weightdm+2|
7,|swimmer=1||weightdm+1|
8,|swimmer=1||weightdm-1|
9,|triphibian=1||weightdm-7|
10,|triphibian=1||weightdm-6|
11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-5|

:Special Attribute General
2-9,
10-11,|flyer=1||weightdm-6|
12,|flyer=1||weightdm-3|


:Weight Lookup
1,1 kg
2,3 kg
3,6 kg
4,12 kg
5,25 kg
6,50 kg
7,100 kg
8,200 kg
9,400 kg
10,800 kg
11,1&nbsp;600 kg
12-13,3&nbsp;200 kg
14,6 tonnes
15,12 tonnes
16,24 tonnes
17,30 tonnes
18,36 tonnes
19,40 tonnes
20,44 tonnes

:Weight Lookup Custom
1,{Calc~{Dice~3d667}\10/100} kg
2,{Calc~{Dice~3d100+150}\10/10} kg
3,{Calc~{Dice~3d200+300}\10/10} kg
4,{Calc~{Dice~3d400+600}\100} kg
5,{Calc~{Dice~3d84+123}\10} kg
6,{Calc~{Dice~3d167+248}\10} kg
7,{Calc~{Dice~3d334+498}\10} kg
8,{Calc~{Dice~3d667+998}\100}0 kg
9,{Calc~{Dice~3d134+198}\10}0 kg
10,|roll={Dice~3d267+398}|{If~%roll%>=1000?{Calc~%roll%\1000}&nbsp;}{If~%roll%>1000?{If~{Calc~(%roll%-1000)}<100?0}}{Calc~(%roll%-((%roll%\1000)*1000))\10}0 kg
11,|roll={Dice~3d534+798}|{If~%roll%>=1000?{Calc~%roll%\1000}&nbsp;}{Calc~(%roll%-((%roll%\1000)*1000))\100}00 kg
12-13,|roll={Dice~3d107+158}|{Calc~%roll%\100}&nbsp;{Calc~(%roll%-((%roll%\100)*100))\10}00 kg
14,{Calc~{Dice~3d100+150}\10/10} tonnes
15,{Calc~{Dice~3d200+300}\10/10} tonnes
16,{Calc~{Dice~3d80+120}\10} tonnes
17,{Calc~{Dice~3d100+150}\10} tonnes
18,{Calc~{Dice~3d120+180}\10} tonnes
19,{Calc~{Dice~3d134+198}\10} tonnes
20,{Calc~{Dice~3d147+218}\10} tonnes

:Hits
1,1/0
2,1/1
3,{Dice~1d6}/1
4,{Dice~1d6}/2
5,{Dice~1d6}/3
6,{Dice~1d6}/{Dice~1d6}
7,{Dice~1d6}/{Dice~1d6+1}
8,{Dice~2d6}/{Dice~1d6+1}
9,{Dice~2d6}/{Dice~1d6+1}
10,{Dice~2d6}/{Dice~1d6+3}
11,{Dice~3d6}/{Dice~1d6+3}
12-13,{Dice~3d6}/{Dice~1d6+4}
14,{Dice~3d6}/{Dice~2d6}
15,{Dice~3d6}/{Dice~2d6+2}
16,{Dice~4d6}/{Dice~3d6}
17,{Dice~5d6}/{Dice~3d6}
18,{Dice~5d6}/{Dice~3d6+3}
19,{Dice~5d6}/{Dice~3d6+6}
20,{Dice~6d6}/{Dice~3d6+6}

:RCS Integrity
# (+)1 becomes 1d6
# 1D becomes 3d6+10
# 1D+1 becomes 4d6+10
# 2D becomes 6d6+20
# 2D+1 becomes 7d6+20
# etc.
1,{Dice~1d6}/0
2,{Dice~1d6}/{Dice~1d6}
3,{Dice~3d6+10}/{Dice~1d6}
4,{Dice~3d6+10}/{Dice~2d6}
5,{Dice~3d6+10}/{Dice~3d6}
6,{Dice~3d6+10}/{Dice~3d6+10}
7,{Dice~3d6+10}/{Dice~4d6+10}
8,{Dice~6d6+20}/{Dice~4d6+10}
9,{Dice~6d6+20}/{Dice~4d6+10}
10,{Dice~6d6+20}/{Dice~7d6+10}
11,{Dice~9d6+30}/{Dice~7d6+10}
12-13,{Dice~9d6+30}/{Dice~8d6+10}
14,{Dice~9d6+30}/{Dice~6d6+20}
15,{Dice~9d6+30}/{Dice~8d6+20}
16,{Dice~12d6+40}/{Dice~9d6+30}
17,{Dice~15d6+50}/{Dice~9d6+30}
18,{Dice~15d6+50}/{Dice~12d6+30}
19,{Dice~15d6+50}/{Dice~15d6+30}
20,{Dice~18d6+60}/{Dice~15d6+30}

:Natural Weapons
<|weaponhits=2|
1,Horns{If~%weapondata% = 1? |pen=5||blk=1|[Wound Modifier=%weightroll%]} and Hooves|pen=4||blk=0||weaponhits=2|
2,Horns|pen=5||blk=1|
3,Hooves{If~%weapondata% = 1? |pen=4||blk=0|[Wound Modifier=%weightroll%]} and Teeth|pen=4||blk=0||weaponhits=2|
4,Hooves|pen=4||blk=0|
5,Horns{If~%weapondata% = 1? |pen=5||blk=1|[Wound Modifier=%weightroll%]} and Teeth|pen=4||blk=0||weaponhits=2|
6,Thrasher|pen=8||blk=1|
7,Claws{If~%weapondata% = 1? |pen=3||blk=1|[Wound Modifier=%weightroll%]} and Teeth|pen=4||blk=0||weaponhits=2|
8,Teeth|pen=4||blk=0|
9,Claws|pen=3||blk=1|
10,Claws|pen=3||blk=1|
11,Thrasher|pen=8||blk=1|
12,Claws{If~%weapondata% = 1? |pen=3||blk=1|[Wound Modifier=%weightroll%]} and Teeth|pen=4||blk=0||weaponhits=2|
13,Claws|pen=3||blk=1|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}
14,Stinger|pen=5||blk=0||weaponhits=3|
15,Claws {If~%weapondata% = 1?|pen=3||blk=1||weaponbonus=1|[Wound Modifier=%weightroll%]/+ 1} and Teeth|pen=4||blk=0|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}|weaponhits=2|
16,Teeth|pen=4||blk=0|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}
17,Blade (as blade)|pen=3||blk=2|
18,Long Spine (as pike)|pen=2||blk=1||weaponhits=3|
19,Large Blade (as broadsword)|pen=7||blk=2||weaponhits=3|
20,Projectile (Med Rng)|pen=0||weaponhits=3|
>{If~%weapondata% = 1? [Wound Modifier=%weightroll%]}

:Swimmer Weapons
<|weaponhits=2|
1-8,Teeth|pen=4||blk=0|
9,Thrasher|pen=8||blk=1|
10,Teeth{If~%weapondata% = 1? |pen=4||blk=0|[Wound Modifier=%weightroll%]} and Thrasher|pen=8||blk=1||weaponhits=2|
11,Thrasher|pen=8||blk=1|
12,Teeth|pen=4||blk=0|
13,Teeth|pen=4||blk=0|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}
14,Stinger|pen=5||blk=0||weaponhits=3|
15-16,Teeth|pen=4||blk=0|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}
17,Blade|pen=3||blk=2|
18,Long Spine|pen=2||blk=1||weaponhits=3|
19,Large Blade|pen=7||blk=2||weaponhits=3|
20,Teeth {If~%weapondata% = 1?|pen=4||blk=0||weaponbonus=1|[Wound Modifier=%weightroll%]/+ 1} and Thrasher|pen=8||blk=1|{If~%weapondata% = 1?|weaponbonus=1|/ + 1}|weaponhits=2|
>{If~%weapondata% = 1? [Wound Modifier=%weightroll%]}

:Wound Modifier
<&#123;DV
1-2,{If~%standardweapon%=1 ?|temp={Dice~1d6-3}||temp>0||weaponhits-%temp%||weaponhits>1|%weaponhits%/%weaponhits%-(1D-3)}
3,{Calc~%weaponhits%-1}
4-7,%weaponhits%
8,{Calc~%weaponhits%+1}
9,{If~%standardweapon%=1 ?|temp={Dice~1d6-3}||temp>0||weaponhits+%temp%|%weaponhits%/%weaponhits%+(1D-3)}
10,{If~%standardweapon%=1 ?|weaponhits+{Dice~1d6}|%weaponhits%/%weaponhits%+1D}
11,{If~%standardweapon%=1 ?|weaponhits+{Dice~2d6}|%weaponhits%/%weaponhits%+2D}
12-13,{If~%standardweapon%=1 ?|weaponhits+{Dice~3d6}|%weaponhits%/%weaponhits%+3D}
14-15,{If~%standardweapon%=1 ?|weaponhits*{Dice~1d6}|%weaponhits%/%weaponhits%&times;1D}
16,{If~%standardweapon%=1 ?|weaponhits*{Dice~1d6+1}|%weaponhits%/%weaponhits%&times;(1D+1)}
17-18,{If~%standardweapon%=1 ?|weaponhits*{Dice~2d6}|%weaponhits%/%weaponhits%&times;2D}
19,{If~%standardweapon%=1 ?|weaponhits*{Dice~2d6+2}|%weaponhits%/%weaponhits%&times;(2D+2)}
20,{If~%standardweapon%=1 ?|weaponhits*{Dice~3d6}|%weaponhits%/%weaponhits%&times;3D}
> Pen %pen% Blk %blk%{If~%weaponbonus% > 0 ?, DM+%weaponbonus%}&#125;|weaponhits=2|

:Natural Armour
1-3,{If~%weapondata% = 1?, AV0}
4,{IIf~%weapondata% = 1?, AV(1):, Jack}
5-9,{If~%weapondata% = 1?, AV0}
10,{IIf~%weapondata% = 1?, AV(1):, Jack}
11-12,{If~%weapondata% = 1?, AV0}
13,{IIf~%weapondata% = 1?, AV3:, Mesh + 1}
14,{IIf~%weapondata% = 1?, AV6:, Cloth + 1}
15,{IIf~%weapondata% = 1?, AV2:, Mesh}
16,{IIf~%weapondata% = 1?, AV5:, Cloth}
17,{IIf~%weapondata% = 1?, AV12:, Combat + 4}
18,{IIf~%weapondata% = 1?, AV/[10/]:, Reflec}
19,{IIf~%weapondata% = 1?, AV1/AV/[6/]:, Ablat}
20,{IIf~%weapondata% = 1?, AV10:, Battle}

:Behaviour
1,{Select~%method%,
_Filter,F{Dice~1d6+2} Ap |roll={Dice~1d6-5}||roll>0|S%roll%,
_Intermittent,F{Dice~1d6+3} A{Dice~1d6+3} |roll={Dice~1d6-4}||roll>1|S%roll%,
_Grazer,F{Dice~1d6-1} A{Dice~1d6+2} |roll={Dice~1d6-2}||roll>2|S%roll%,
_Gatherer,A{Dice~1d6+3} F{Dice~1d6+2} |roll={Dice~1d6-3}||roll>1|S%roll%,
_Hunter,A{Dice~1d6} F{Dice~1d6+3} |roll={Dice~1d6-3}||roll>1|S%roll%,
_Eater,A{Dice~1d6} F{Dice~1d6+2} |roll={Dice~1d6-4}||roll>1|S%roll%,
_Pouncer,As Fs |roll={Dice~1d6-4}||roll>1|S%roll%,
_Chaser,Am F{Dice~1d6+3} |roll={Dice~1d6-2}||roll>2|S%roll%,
_Trapper,As F{Dice~1d6+2} |roll={Dice~1d6-5}||roll>0|S%roll%,
_Siren,As F{Dice~1d6+3} |roll={Dice~1d6-4}||roll>0|S%roll%,
_Killer,A{Dice~1d6} F{Dice~1d6+3} |roll={Dice~1d6-3}||roll>1|S%roll%,
_Hijacker,A{Dice~1d6+1} F{Dice~1d6+2} |roll={Dice~1d6-4}||roll>1|S%roll%,
_Intimidator,A{Dice~1d6+2} F{Dice~1d6+1} |roll={Dice~1d6-4}||roll>1|S%roll%,
_Carrion-Eater,A{Dice~1d6+3} F{Dice~1d6+2} |roll={Dice~1d6-3}||roll>1|S%roll%,
_Reducer,A{Dice~1d6+3} F{Dice~1d6+2} |roll={Dice~1d6-4}||roll>1|S%roll%,
#Default Behaviour for Unknown Niche
_*A{Dice~1d6+3} F{Dice~1d6} |roll={Dice~1d6-3}||roll>1|S%roll%}

# ANIMAL DATA REPORT FUNCTION
# Designed to spit out a human-readable description of the creature's data.
:Animal Data
1,[FxnSetEnvironmentType]
_ ({If~%includebiome%=1?[Terrain Type=%terraintype%] Biome}
_{If~%includebiome%=1?, }Size [FxnUCPLetter=%weightroll%], {If~%exactweight%=1?[Weight Lookup Custom=%weightroll%]/[Weight Lookup=%weightroll%]}
_, {If~%integrity%=1?Integrity [RCS Integrity=%weightroll%]/Hits [Hits=%weightroll%]}
_, [FxnNicheNaturalWeaponsRoll]{If~{And~%swimmerweapons%=1,%swimmer%=1}=1 ?[Swimmer Weapons=%roll%]/[Natural Weapons=%roll%]}
_|doonce=0|[FxnNicheNaturalArmourBonus][FxnArmourRoll]|roll>1||roll<20|[Natural Armour]
_, [Behaviour]
>)

:FxnClearVariables
1,|typedm=0||weightdm=0||swimmer=0||amphibian=0||triphibian=0||flyer=0|
_|environmenttype=1||weaponhits=2||weaponbonus=0||niche=0||method=0|
_|doonce=0||armourdm=0|

:FxnUCPLetter
1,1
2,2
3,3
4,4
5,5
6,6
7,7
8,8
9,9
10,A
11,B
12,C
13,D
14,E
15,F
16,G
17,H
18,J
19,K
20,L