# TRAVELLER ENCOUNTER TABLE
# Generates a random encounter table for a random biome.  Parameters can choose
#  whether to generate an encounter table for a more specific biome.

%randomterrain%,1
%terraintype%,0
%houseanimal%,2

@randomterrain,1,Generate a random terrain type?,Yes,No
@terraintype,3,If "no" choose the terrain type:,Clear (Road/Open),Prairie (Plain/Steppe),Rough (Hills/Foothills),Broken (Badlands),Mountain (Alpine),Forest (Woods),Jungle (Rainforest),River (Stream/Creek),Swamp (Bog),Marsh (Wetland),Desert (Dunes),Beach (Shore/Sea Edge),Surface (Ocean/Sea),Shallows (Ocean/Sea),Depths (Ocean/Sea),Bottom (Ocean/Sea),Sea Cave/Cavern,Sargasso (Seaweed),Ruins/(Old City),Cave (Cavern),Chasm (Crevasse/Abyss),Crater (Hollow)
@houseanimal,2,(House rule) Apply standard house rules for animals (swimmer weapons + exact weight + integrity)?,Yes,No

%roll%,0

;Start
1,{If~%randomterrain%=1 ?|terraintype={Dice~1d22}|}
_[FxnSetExternalVariables]
_[Start HTML]
_|roll=1|{While~%roll%<12,[Table Row]}
_[End HTML]

;Start HTML
1,<table style="width: 100/%; border: 1px solid; border-collapse: collapse">
_<tr><th colspan="2">Encounter Table: [Traveller Random Creature.Terrain Type=%terraintype%]</th></tr>
_<tr><th style="width: 32px"><span style="border-bottom: 1px solid">2D</span></th><th><span style="text-align: left; width: 100/%; border-bottom: 1px solid">&nbsp;Result</span></th></tr>

;Table Row
1,<tr><td style="text-align: center">|roll+1|%roll%</td><td>[Traveller Random Creature.Start]</td></tr>

;End HTML
1,</table>

;FxnSetExternalVariables
1,|Traveller Random Creature!terraintype=%terraintype%|
_|Traveller Random Creature!randomterrain=2|
_|Traveller Random Creature!randomevents=1|
_|Traveller Random Creature!includebiome=2|
_{If~%houseanimal%=1 ?|Traveller Random Creature!swimmerweapons=1|
_|Traveller Random Creature!exactweight=1|
_|Traveller Random Creature!integrity=1|}